1.新しいシートを挿入したら、常にブックの最後に移動する 引数Shを使えますから、
Sh.Move After:= Sheets(Sheets.Count)
直前の枚数をかぞえてその後ろに移動します。

2. こんどは、シートに名前をつけるようにします。
名前は InputBox によりユーザーが入力することにします。シート名を格納するための変数temp宣言してつかいます。

Private Sub Workbook_NewSheet(ByVal Sh As Object)
    Dim temp As String
    temp = InputBox("シート名を入力してください")
    Sh.Name = temp
End Sub

3. 上記マクロで気をつけなければならないことは、入力ダイアログで未入力でOKをクリックしたり、キャンセルしたりすると、エラーが発生してしまいます。
しかし、エラーが発生しても処理をつづけ、正しい名前を入力するようにメッセージで促すことにした方が、良いでしょう。
最後に、On Error GoTo 0ステートメントを利用して、一度設定したプログラムのエラー処理を無効にしています。

Private Sub Workbook_NewSheet(ByVal Sh As Object)
    Dim temp As String
    temp = InputBox("シート名を入力してください")
    On Error Resume Next
    Sh.Name = temp
    If Err.Number <> 0 Then
        MsgBox "シート名を正しく入力してください", vbExclamation
        Application.DisplayAlerts = False
        Sh.Delete
        Application.DisplayAlerts = True
    End If
    On Error GoTo 0
End Sub

4. 入力ダイアログで未入力でOKをクリックしたり、キャンセルしたりすると、エラーが発生。 そこでエラーでもメッセージを表示する。OKをクリックすると、シートが削除される。

5. では例として、新しいシートを挿入したら、自動的にそのシートを一番後ろ右側に移動し、 前から並んでいるシートの順で、名前を規則的に設定するプロシージャを考えます。 そして、すでに何枚かシートがあるわけですから、そのシートの枚数を数えるための変数としてiをつかいます。 グラフシートは対象に入れないことにします。

Private Sub Workbook_NewSheet(ByVal Sh As Object)
    Dim i As Integer
    If TypeName(Sh) = "Worksheet" Then
        Sh.Move After:=Worksheets(Worksheets.Count)
        For i = 1 To Worksheets.Count
            Worksheets(i).Name = "令和3年" & _
                Format(Now, "mm月") & "_" & Format(i, "00")
        Next i
    End If
End Sub

6. 上記コードでは月だけをNow関数から取得しています。その後ろはシートの通し番号になっています。

7. シート名に月と日付を使いたい場合は
　Format(Now, "mmdd")　のようにすれば　0810のように日付が入り、後ろは通し番号となります。

8. 次回はWorkbook_SheetChangeについて紹介します。